怎么在ORACLE中配置郵件服務(wù)器？很多新手對此不是很清楚，為了幫助大家解決這個難題，下面小編將為大家詳細(xì)講解，有這方面需求的人可以來學(xué)習(xí)下，希望你能有所收獲。

創(chuàng)新互聯(lián)建站專注于企業(yè)全網(wǎng)營銷推廣、網(wǎng)站重做改版、廣宗網(wǎng)站定制設(shè)計、自適應(yīng)品牌網(wǎng)站建設(shè)、html5、購物商城網(wǎng)站建設(shè)、集團公司官網(wǎng)建設(shè)、外貿(mào)營銷網(wǎng)站建設(shè)、高端網(wǎng)站制作、響應(yīng)式網(wǎng)頁設(shè)計等建站業(yè)務(wù)，價格優(yōu)惠性價比高，為廣宗等各大城市提供網(wǎng)站開發(fā)制作服務(wù)。

1 創(chuàng)建 ACL

BEGIN
  dbms_network_acl_admin.create_acl(acl     => 'email.xml',
                   DESCRIPTION => 'Enables network permissions for the e-mail server',
                   principal  => 'C##ESD_MONITOR', --表示賦予哪個用戶 必須大寫
                   is_grant  => TRUE,
                   PRIVILEGE  => 'resolve',
                   start_date => NULL,
                   end_date  => NULL);
END;

2 賦予權(quán)限

begin
dbms_network_acl_admin.add_privilege(acl    => 'email.xml', --同上xml名稱
                     principal => 'C##ESD_MONITOR', --表示賦予哪個用戶 必須大寫
                     is_grant  => TRUE,
                     privilege => 'connect', --權(quán)限名
                     start_date => null,
                     end_date  => null);
end;

3 設(shè)置端口

begin
 dbms_network_acl_admin.assign_acl (    -- 該段命令意思是允許訪問acl名為utl_sendmail.xml下授權(quán)的用戶，使用oracle網(wǎng)絡(luò)訪問包，所允許訪問的目的主機，及其端口范圍。
  acl    => 'email.xml',
  host    => '*'-- ,       -- ip地址或者域名，填寫http://localhost:9000/hello與http://localhost:9000/是會報host無效的
                      -- 且建議使用ip地址或者使用域名，若用localhost，當(dāng)oracle不是安裝在本機上的情況下，會出現(xiàn)問題
  -- lower_port => 9000,           -- 允許訪問的起始端口號
  -- upper_port => Null           -- 允許訪問的截止端口號
 );
 end;

4 查詢權(quán)限設(shè)置情況

SELECT acl,
    principal,
    privilege,
    is_grant,
    TO_CHAR(start_date, 'DD-MON-YYYY') AS start_date,
    TO_CHAR(end_date, 'DD-MON-YYYY') AS end_date
 FROM dba_network_acl_privileges;

5 創(chuàng)建郵件發(fā)送存儲過程

create or replace procedure send_mail(p_recipient VARCHAR2, -- 郵件接收人
           p_subject  VARCHAR2, -- 郵件標(biāo)題
           p_message  VARCHAR2, -- 郵件正文
           p_type   number -- 1文本 2html
           ) as
  --下面四個變量請根據(jù)實際郵件服務(wù)器進(jìn)行賦值
  v_mailhost VARCHAR2(30) := 'smtp.qq.com'; --SMTP服務(wù)器地址
  v_user   VARCHAR2(30) := '111@qq.com'; --登錄SMTP服務(wù)器的用戶名
  v_pass   VARCHAR2(20) := '111'; --登錄SMTP服務(wù)器的密碼 授權(quán)碼
  v_sender  VARCHAR2(50) := '111@qq.com'; --發(fā)送者郵箱，一般與 ps_user 對應(yīng)
  v_conn UTL_SMTP.connection; --到郵件服務(wù)器的連接
  v_msg varchar2(4000); --郵件內(nèi)容
 BEGIN
  v_conn := UTL_SMTP.open_connection(v_mailhost, 25);
  UTL_SMTP.ehlo(v_conn, v_mailhost); --是用 ehlo() 而不是 helo() 函數(shù)
  --否則會報：ORA-29279: SMTP 永久性錯誤: 503 5.5.2 Send hello first.
  UTL_SMTP.command(v_conn, 'AUTH LOGIN'); -- smtp服務(wù)器登錄校驗
  UTL_SMTP.command(v_conn,
           UTL_RAW.cast_to_varchar2(UTL_ENCODE.base64_encode(UTL_RAW.cast_to_raw(v_user))));
  UTL_SMTP.command(v_conn,
           UTL_RAW.cast_to_varchar2(UTL_ENCODE.base64_encode(UTL_RAW.cast_to_raw(v_pass))));
  UTL_SMTP.mail(v_conn, '<' || v_sender || '>'); --設(shè)置發(fā)件人 注：網(wǎng)上很多資料直接寫v_sender，這樣寫會報ORA-29279: SMTP 500 error
  UTL_SMTP.rcpt(v_conn, '<' || p_recipient || '>'); --設(shè)置收件人
  UTL_SMTP.open_data(v_conn); --打開流
  if p_type = 1 then
   -- 創(chuàng)建要發(fā)送的郵件內(nèi)容 注意報頭信息和郵件正文之間要空一行
   v_msg := 'Date:' || TO_CHAR(SYSDATE, 'dd mon yy hh34:mi:ss') ||
        UTL_TCP.CRLF || 'From: ' || '<' || v_sender || '>' ||
        UTL_TCP.CRLF || 'To: ' || '<' || p_recipient || '>' ||
        UTL_TCP.CRLF || 'Subject: ' || p_subject || UTL_TCP.CRLF ||
        UTL_TCP.CRLF -- 這前面是報頭信息
        || p_message; -- 這個是郵件正文
   UTL_SMTP.write_raw_data(v_conn, UTL_RAW.cast_to_raw(v_msg)); --這樣寫標(biāo)題和內(nèi)容都能用中文
  elsif p_type = 2 then
   UTL_SMTP.write_data(v_conn,
             'From:' || '<' || v_sender || '>' || utl_tcp.CRLF);
   UTL_SMTP.write_data(v_conn,
             'To:' || '<' || p_recipient || '>' ||
             utl_tcp.crlf);
   UTL_SMTP.write_raw_data(v_conn,
               UTL_RAW.cast_to_raw(convert('Subject:' ||
                             p_subject ||
                             utl_tcp.CRLF,
                             'ZHS16GBK')));
   UTL_SMTP.write_raw_data(v_conn,
               UTL_RAW.cast_to_raw(convert('Content-Type:text/html;charset=GBK' ||
                             utl_tcp.CRLF,
                             'ZHS16GBK')));
   UTL_SMTP.write_data(v_conn, utl_tcp.CRLF);
   UTL_SMTP.write_raw_data(v_conn,
               UTL_RAW.cast_to_raw(convert(p_message,
                             'ZHS16GBK'))); --這樣寫標(biāo)題和內(nèi)容都能用中文
  end if;
  UTL_SMTP.close_data(v_conn); --關(guān)閉流
  UTL_SMTP.quit(v_conn); --關(guān)閉連接
 EXCEPTION
  WHEN OTHERS THEN
   DBMS_OUTPUT.put_line(DBMS_UTILITY.format_error_stack);
   DBMS_OUTPUT.put_line(DBMS_UTILITY.format_call_stack);
 END;

看完上述內(nèi)容是否對您有幫助呢？如果還想對相關(guān)知識有進(jìn)一步的了解或閱讀更多相關(guān)文章，請關(guān)注創(chuàng)新互聯(lián)行業(yè)資訊頻道，感謝您對創(chuàng)新互聯(lián)的支持。

名稱欄目：怎么在ORACLE中配置郵件服務(wù)器-創(chuàng)新互聯(lián)
文章轉(zhuǎn)載：http://weahome.cn/article/dosghh.html