這篇文章主要介紹了如何編寫IP地址設置切換批處理，具有一定借鑒價值，感興趣的朋友可以參考下，希望大家閱讀完這篇文章之后大有收獲，下面讓小編帶著大家一起了解一下。

成都創(chuàng)新互聯(lián)公司，專注為中小企業(yè)提供官網(wǎng)建設、營銷型網(wǎng)站制作、成都響應式網(wǎng)站建設、展示型成都網(wǎng)站制作、成都做網(wǎng)站等服務，幫助中小企業(yè)通過網(wǎng)站體現(xiàn)價值、有效益。幫助企業(yè)快速建站、解決網(wǎng)站建設與網(wǎng)站營銷推廣問題。

修正一個提取網(wǎng)絡連接名稱的錯誤，原因在于之前在FOR中使用空格作為分隔符
如果網(wǎng)絡連接名為“本地連接 2”，原來只會識別成“本地連接”，從而導致設置失敗
現(xiàn)已更正

說明：1、可以選擇要設置的網(wǎng)絡連接
2、可以手動設定固定IP，也可以通過DHCP自動獲取
3、可以在批處理中預設多組MAC與IP對應數(shù)據(jù)，當內網(wǎng)有MAC綁定時可快速查詢相應IP
4、DNS設置提供四類數(shù)據(jù)（中國電信、 中國聯(lián)通/中國網(wǎng)通、中國移動/ 國鐵通、內網(wǎng)網(wǎng)關）
DNS為福州地區(qū)數(shù)據(jù)，請自行更改為當?shù)馗鲗拵н\營商DNS
5、再添加一功能：在設置完畢后可以選擇是否當本機MAC及IP數(shù)據(jù)添加到本批處理中以便下次自動識別

批處理代碼如下：

代碼如下:

@title IP地址設置切換批處理 

@echo off & setlocal enabledelayedexpansion

if exist "%windir%\system32\slmgr.vbs" (
echo.&echo 本批處理在 VISTA 以及 WIN7 中須以管理員身份運行
echo.&echo 請查看批處理窗口標題欄信息開頭是否為“管理員：”
echo.&echo 如符合上述條件可按任意鍵繼續(xù)，否則請退出批處理后以管理員身份重新運行
pause>nul
)

set n=0
for /f "delims=:" %%a in ('ipconfig/all^|findstr /i /b /c:"Ethernet adapter"') do (set /a n=!n!+1&set str=%%a&set net!n!=!str:~17!)
set n=0
for /f "tokens=2 delims=:" %%a in ('ipconfig/all^|findstr /i /c:"Description"') do (set /a n=!n!+1&set netcard!n!=%%a)
set n=0
for /f "tokens=2 delims=:" %%a in ('ipconfig/all^|findstr /i /c:"Physical Address"') do (set /a n=!n!+1&set MAC!n!=%%a)

:net
echo.&echo 請選擇當前本機要設置的網(wǎng)絡鏈接：
for /l %%a in (1,1,!n!) do (
echo.
echo %%a - !net%%a! - !netcard%%a!
echo MAC 地址：!MAC%%a!
)
echo.&set num=&set /p num=請輸入序號并回車加以選擇：
cls
if defined net%num% (set NET=!net%num%!&set MAC=!MAC%num%: =!&set MAC=!MAC:~0,17!) else (echo.&echo 輸入的序號有誤，請重新選擇！&goto :net)

:lib
set MASK=255.255.255.0
set GATE=192.168.0.1
cls&echo.&echo 當前 !NET! 的 MAC 為 !MAC!
for /f "tokens=2 delims=[]" %%a in ('findstr /i "!MAC!" %0') do set IP=%%a
if defined IP (
set inbat=1
echo.&echo 在批處理數(shù)據(jù)庫中找到對應數(shù)據(jù)
echo.&echo IP : !IP!
echo.&echo 子網(wǎng)掩碼 : !MASK!
echo.&echo 網(wǎng)關 : !GATE!
echo.&set /p IP=如需改變 IP 數(shù)據(jù)請手動輸入并回車，如取默認值請直接回車 ：
echo.&set /p MASK=如需改變 子網(wǎng)掩碼 數(shù)據(jù)請手動輸入并回車，如取默認值請直接回車 ：
echo.&set /p GATE=如需改變 網(wǎng)關 數(shù)據(jù)請手動輸入并回車，如取默認值請直接回車 ：
goto :isp
) else (
set inbat=0
echo.&echo 在批處理數(shù)據(jù)庫中未找到對應 IP ，請手動選擇 IP 設置方式
goto :lan
)

:lan
echo.&echo 當前要設置的網(wǎng)絡鏈接是：
echo.&echo !NET! - !netcard%num%!
echo.&echo 請選擇 IP 設置方式：
echo.&echo 1 - 手動設定固定 IP
echo.&echo 2 - DHCP 自動獲取
echo.&set choose=&set /p choose=請輸入序號并回車加以選擇：
cls
if %choose% equ 1 goto :set
if %choose% equ 2 goto :dhcp
echo.&echo 輸入的序號有誤，請重新選擇！&goto :lan

:set
set IP=192.168.0.9
cls&echo.&echo 默認 IP 為 !IP! ，如需改變請手動輸入并回車，如取默認值請直接回車：
echo.&set /p IP=
cls&echo.&echo 默認子網(wǎng)掩碼為 !MASK! ，如需改變請手動輸入并回車，如取默認值請直接回車：
echo.&set /p MASK=
cls&echo.&echo 默認網(wǎng)關為 !GATE! ，如需改變請手動輸入并回車，如取默認值請直接回車：
echo.&set /p GATE=
:isp
cls&echo.&echo 請選擇寬帶線路對應 DNS （福州地區(qū)）：
echo.&echo 1 - 中國電信
echo.&echo 2 - 中國聯(lián)通 / 中國網(wǎng)通
echo.&echo 3 - 中國移動 / 中國鐵通
echo.&echo 4 - 內網(wǎng)網(wǎng)關%GATE%
echo.&set isp=&set /p isp=請輸入序號并回車加以選擇：
if %isp% equ 1 (call :10000&goto :doset)
if %isp% equ 2 (call :10010&goto :doset)
if %isp% equ 3 (call :10086&goto :doset)
if %isp% equ 4 (set DNS1=%GATE%&goto :doset)
echo.&echo 輸入的序號有誤，請重新選擇！&goto :isp
:doset
cls&echo.&echo 正在設置 %NET% ，IP 地址為 %IP%，請稍候...
netsh interface ip set address name="%NET%" static %IP% %MASK% %GATE% 1 >nul
netsh interface ip set dns name="%NET%" static %DNS1% >nul
if defined DNS2 netsh interface ip add dns name="%NET%" %DNS2% 2 >nul
goto :end

:dhcp
cls&echo.&echo 正在設置 %NET% ，自動獲取 IP 及 DNS ，請稍候...
netsh interface ip set address name="%NET%" DHCP >nul 2>nul
netsh interface ip set dns name="%NET%" DHCP >nul 2>nul
goto :end

:end
cls
ipconfig/all
echo.&echo 設置完畢，當前 IP 信息如上，請仔細查看
if !inbat! equ 0 (
echo.&echo 輸入 Y 并回車可將本機 MAC 及 IP 數(shù)據(jù)添加到本批處理中以便下次自動識別
echo.&set /p addbat=若不添加數(shù)據(jù)請直接回車退出：
if /i !addbat! equ Y echo>>%0 [!MAC!]!IP!
) else (pause>nul)
exit

************************************************************
::以下DNS僅供福州地區(qū)使用，請自行更改為本地區(qū)各寬帶運營商DNS

:10000
set DNS1=218.85.152.99
set DNS2=218.85.157.99
goto :eof

:10010
set DNS1=58.22.96.66
set DNS2=218.104.128.106
goto :eof

:10086
set DNS1=222.47.29.93
set DNS2=222.47.62.142
goto :eof
************************************************************
主機MAC與IP分配對應數(shù)據(jù)庫，當內網(wǎng)有MAC綁定時可快速查詢相應IP
可按示例格式（[MAC地址]IP地址）自行添加，每組數(shù)據(jù)單獨一行
示例：
[11-22-33-44-55-66]192.168.0.1
************************************************************

感謝你能夠認真閱讀完這篇文章，希望小編分享的“如何編寫IP地址設置切換批處理”這篇文章對大家有幫助，同時也希望大家多多支持創(chuàng)新互聯(lián)網(wǎng)站建設公司，，關注創(chuàng)新互聯(lián)行業(yè)資訊頻道，更多相關知識等著你來學習!

文章標題：如何編寫IP地址設置切換批處理-創(chuàng)新互聯(lián)
轉載注明：http://weahome.cn/article/ehhig.html