Qt高級——QMake快速入門

一、QMake簡介

qmake是Trolltech公司創(chuàng)建的用來為不同的平臺和編譯器書寫Makefile的工具。
qmake是一個用來簡化在不同平臺間開發(fā)工程的構(gòu)建過程的工具。qmake會自動生成MakeFile文件，可以用于任何軟件項目中，無論是否由Qt編寫。
qmake會注意所有的編譯器和平臺的依賴性，開發(fā)者只需關(guān)注自己的代碼。qmake作為Qt庫和Qt所提供的工具的主要連編工具，可以自動的包含moc和uic的連編規(guī)則。

創(chuàng)新互聯(lián)公司專業(yè)IDC數(shù)據(jù)服務(wù)器托管提供商，專業(yè)提供成都服務(wù)器托管，服務(wù)器租用，達(dá)州主機托管，達(dá)州主機托管，成都多線服務(wù)器托管等服務(wù)器托管服務(wù)。

二、QMake入門教程

1、創(chuàng)建一個工程

創(chuàng)建一個應(yīng)用，包含 hello.cpp、hello.h、main.cpp三個文件。
使用文本編輯器創(chuàng)建一個hello.pro文件，增加源文件、頭文件到工程文件hello.pro。

HEADERS += hello.h
SOURCES += hello.cpp
SOURCES += main.cpp

同時，也可以使用換行符一次增加多個文件。

SOURCES = hello.cpp \
          main.cpp

目標(biāo)名稱會自動設(shè)置，一般與工程文件相同，當(dāng)會用后綴區(qū)別不同的平臺。如，工程文件是hello.pro，Windows平臺的目標(biāo)名稱是hello.exe，Unix平臺的目標(biāo)名稱是hello。如果要使用不同的目標(biāo)名稱，需要在工程文件hello.pro中設(shè)置。如：
TARGET = helloworld
最后就是配置CONFIG變量，對于Qt應(yīng)用程序來說，給CONFIG賦值qt，QMake會鏈接相關(guān)的庫，并確保moc和uic相關(guān)的連編規(guī)則生成到MakeFile文件中。最終的hello.pro工程文件如下：

CONFIG += qt
HEADERS += hello.h
SOURCES += hello.cpp
SOURCES += main.cpp

在工程所在目錄打開命令行終端，使用qmake生成為應(yīng)用生成MakeFile。
qmake -o Makefile hello.pro
對于Visual Studio開發(fā)者，qmake會生成.dsp或.vcproj文件。
qmake -tp vc hello.pro

2、增加工程的調(diào)試版

應(yīng)用程序的 release版本不包含調(diào)試符號或其它調(diào)試信息。在開發(fā)過程中，生成帶調(diào)試信息的應(yīng)用程序調(diào)試版本是很有用的。通過增加debug到CONFIG變量可以生成應(yīng)用程序的調(diào)試版本。

CONFIG += qt debug
HEADERS += hello.h
SOURCES += hello.cpp
SOURCES += main.cpp

3、增加特定平臺的源文件

應(yīng)用程序中特定平臺部分的源碼需要保持平臺獨立代碼的分離?，F(xiàn)在有hellowin.cpp和hellounix.cpp兩個新文件。不能直接增加這兩個文件到SOURCES變量，因為這會導(dǎo)致這兩個文件直接生成到MakeFile文件，需要在qmake所運行的平臺的代碼塊中獨立處理。
對于Windows平臺，在一個簡單的代碼塊中增加平臺獨立的文件。

win32 {
SOURCES += hellowin.cpp}

如果qmake運行在Windows平臺上，會增加hellowin.cpp文件到源文件列表。如果qmake運行在其它平臺上，會忽略?，F(xiàn)在創(chuàng)建一個代碼塊增加和Unix平臺相關(guān)的文件。

unix {
    SOURCES += hellounix.cpp}

工程文件hello.pro文件如下：

CONFIG += qt debug
HEADERS += hello.h
SOURCES += hello.cpp
SOURCES += main.cpp
win32 {
    SOURCES += hellowin.cpp}
unix {
    SOURCES += hellounix.cpp}

4、如果文件不存在中止qmake過程

如果某個文件不存在，不生成MakeFile文件?？梢允褂胑xists()函數(shù)檢查一個文件是否存在。通過使用error()函數(shù)可以中止qmake執(zhí)行過程。對main.cpp文件檢查如下：

!exists( main.cpp ) {
    error( "No main.cpp file found" )}

如果main.cpp文件存在，exists(main.cpp)為true。
如果main.cpp文件不存在，!exists(main.cpp)為true。

CONFIG += qt debug
HEADERS += hello.h
SOURCES += hello.cpp
SOURCES += main.cpp
win32 {
    SOURCES += hellowin.cpp}
unix {
SOURCES += hellounix.cpp}
!exists( main.cpp ) {
    error( "No main.cpp file found" )}

5、檢查多個條件

假設(shè)在Windows平臺上，使用命令行運行應(yīng)用程序，想通過qDebug()函數(shù)查看輸出狀態(tài)。除非在應(yīng)用程序構(gòu)建過程中使用console設(shè)置，否則看不到輸出狀態(tài)信息。通過將console增加到CONFIG變量可以在生成的MakeFile文件中生成相應(yīng)的設(shè)置。
如果只在Windows平臺上debug版本時查看輸出信息。代碼如下：

win32 {
    debug {
        CONFIG += console
    }}

內(nèi)嵌的作用域也可以使用冒號（:）連接在一起。

CONFIG += qt debug
HEADERS += hello.h
SOURCES += hello.cpp
SOURCES += main.cpp
win32 {
    SOURCES += hellowin.cpp}
unix {
SOURCES += hellounix.cpp}
!exists(main.cpp) {
    error("No main.cpp file found")}
win32:debug {
    CONFIG += console}

三、QMake創(chuàng)建工程

本文將講述如何設(shè)置基于Qt的三種通用工程類型的qmake工程文件。

1、QMake創(chuàng)建應(yīng)用程序

app模板會告訴qmake生成一個構(gòu)建應(yīng)用程序的MakeFile。使用app模板，應(yīng)用的類型可以增加一個選項到CONFIG變量定義中。
windows：應(yīng)用是一個Windows GUI應(yīng)用程序
console：應(yīng)用是一個Windows控制臺應(yīng)用。
使用app模板時，下列qmake系統(tǒng)變量會被識別，可以在應(yīng)用程序的.pro文件中使用。
HEADERS：應(yīng)用程序的頭文件列表
SOURCES：應(yīng)用程序的源文件列表
FORMS：應(yīng)用程序的UI（Qt Designer創(chuàng)建）文件列表
LEXSOURCES：應(yīng)用程序的LEX原文件列表
YACCSOURCES：應(yīng)用程序的YACC源文件列表
TARGET：應(yīng)用程序的可執(zhí)行文件名稱
DESTDIR：生成的目標(biāo)文件的存放目錄
DEFINES：應(yīng)用程序指定的預(yù)定義預(yù)處理器符號
INCLUDEPATH：編譯器的搜索頭文件路徑
DEPENDPATH：應(yīng)用程序的依賴查找路徑
VPATH：尋找補充文件的搜索路徑
DEF_FILE： 應(yīng)用程序鏈接的.def文件，僅支持Windows。
RC_FILE：應(yīng)用程序的資源文件，僅支持Windows。
RES_FILE：應(yīng)用程序鏈接的資源文件，僅支持Windows。
開發(fā)者可以直接使用有值的qmake系統(tǒng)變量，不必指定任何值。qmake會自動增加需要的默認(rèn)值。
實例工程文件如下：

TEMPLATE = app
DESTDIR  = c:/helloapp
HEADERS += hello.h
SOURCES += hello.cpp
SOURCES += main.cpp
DEFINES += QT_DLL
CONFIG  += qt warn_on release

對于單個值的數(shù)據(jù)項，如模板或目的目錄，使用“=”，但多個值的數(shù)據(jù)項需要使用“+=”增加到已經(jīng)存在相應(yīng)類型的數(shù)據(jù)項中。如果使用“=”會使用新的值替換原來的值，例如，DEFINES=QT_DLL，所有其它的定義都會被刪除。

2、QMake創(chuàng)建庫

lib模板告訴qmake生成構(gòu)建一個庫的MakeFile。使用lib模板時，除了app模板支持的系統(tǒng)變量，也支持VERSION變量?？梢允褂眠@些變量在.pro文件中指定庫的相關(guān)信息。當(dāng)使用lib模板時，以下選項需要增加到CONFIG變量決定要構(gòu)建的庫的類型。
dll：庫是一個共享庫
staticlib：庫是一個靜態(tài)庫
plugin：庫是一個插件，也支持dll選項
VERSION變量指定庫的版本信息
庫的目標(biāo)文件名是平臺獨立的。例如，X11和Mac OS X，庫名稱使用lib 前綴，Windows平臺上，庫文件名不增加任何前綴。

3、QMake創(chuàng)建插件

插件使用lib模板構(gòu)建，告訴qmake生成一個工程的MakeFile。
VERSION變量用于指定插件的版本信息。
就像普通庫一樣，VERSION變量用于指定插件的版本信息。Qt Designer插件會使用一套依賴于Qt配置的特定配置集進(jìn)行構(gòu)建。為了方便起見，這些設(shè)置可以通過增加designer到工程CONFIG變量開啟。例如：
CONFIG += designer plugin

4、QMake創(chuàng)建Debug 和Release

某些時候，構(gòu)建同時支持debug和release的工程是必要的。雖然CONFIG變量有debug和release選項，但是debug選項會覆蓋release選項。
為了開啟工程同時支持debug和release，必須在CONFIG變量增加debug_and_release選項。

CONFIG += debug_and_release

CONFIG(debug, debug|release) {
    TARGET = debug_binary} else {
    TARGET = release_binary}

以上代碼塊會修改每一種模式的構(gòu)建目標(biāo)，確保目標(biāo)有不同的文件名稱。為目標(biāo)提供不同的名稱可以確保目標(biāo)相互間不會被覆蓋。
當(dāng)qmake處理工程文件時，會生成一個允許支持debug和release模式的MakeFile規(guī)則?？梢酝ㄟ^以下方式調(diào)用：
make all
build_all選項增加到工程文件的CONFIG變量，可以確保工程默認(rèn)會被兩種模式編譯。
CONFIG += build_all
這會允許Makefile使用默認(rèn)規(guī)則處理。
make
build_all選項也可以確保目標(biāo)的兩個版本在安裝規(guī)則被調(diào)用時被安裝。
make install
可以自定義依賴于目標(biāo)平臺的構(gòu)建目標(biāo)的名稱。例如，一個庫或插件可以在Windows平臺使用不同于Unix平臺的命名規(guī)范。

CONFIG(debug, debug|release) {
    mac: TARGET = $$join(TARGET,,,_debug)
    win32: TARGET = $$join(TARGET,,d)}

在debug模式構(gòu)建時，以上代碼塊的默認(rèn)行為會修改構(gòu)建目標(biāo)使用的名稱。