Shader "Unlit/Demo-SequenceAnimation"
{
 Properties
 {
 _MainTex ("Sequence Frame Image", 2D) = "white" {} // 序列幀動畫紋理
 _Color("Color Tint", Color) = (1, 1, 1, 1)   // 顏色
 _HorizontalAmount("Horizontal Amount", float) = 4 // 行數(shù)
 _VerticalAmount("Vertical Amount", float) = 4  // 列數(shù)
 _Speed("Speed", Range(1, 100)) = 30 // 播放速度
 }
 
 SubShader
 {
 // 由于序列幀圖像通常包含了透明通道，因此可以被當(dāng)成是一個半透明對象。
 // 在這里我們使用半透明的“標(biāo)配”來設(shè)置它的SubShader 標(biāo)簽，即把Queue 和RenderType 設(shè)置成Transparent，
 //把IgnoreProjector 設(shè)置為True
 Tags { "RenderType"="Transparent" "Queue"="Transparent" "IgnoreProjector"="True"}
 LOD 100
 
 Pass
 {
 Tags{"LightMode"="ForwardBase"}
 
 // 由于序列幀圖像通常是透明紋理，我們需要設(shè)置Pass 的相關(guān)狀態(tài)，以渲染透明效果
 // 在Pass 中，我們使用Blend 命令來開啟并設(shè)置混合模式，同時關(guān)閉了深度寫入
 ZWrite Off
 Blend SrcAlpha OneMinusSrcAlpha
 
 CGPROGRAM
 #pragma vertex vert
 #pragma fragment frag
 
 #include "UnityCG.cginc"
 
 struct appdata
 {
 float4 vertex : POSITION;
 float2 uv : TEXCOORD0;
 };
 
 struct v2f
 {
 float2 uv : TEXCOORD0;
 float4 vertex : SV_POSITION;
 };
 
 sampler2D _MainTex;
 float4 _MainTex_ST;
 fixed4 _Color;
 float _HorizontalAmount;
 float _VerticalAmount;
 float _Speed;
 
 v2f vert (appdata v)
 {
 v2f o;
 o.vertex = mul(UNITY_MATRIX_MVP, v.vertex);
 o.uv = TRANSFORM_TEX(v.uv, _MainTex);
 return o;
 }
 
 fixed4 frag (v2f i) : SV_Target
 {
 float time = floor(_Time.y * _Speed);   //所經(jīng)過的時間
 float row = floor(time / _HorizontalAmount); // 第幾行圖片 （和行數(shù)不能對應(yīng)起來）
 float column = time - row * _HorizontalAmount; // 第幾列圖片
 
 //每次更新的量
// float offserX = 1.0 / _HorizontalAmount; 
// float offserY = 1.0 / _VerticalAmount;
// half2 uv = float2(i.uv.x * offsetX, i.uv.y*offsetY);
 
 //將所顯示的圖片縮放至應(yīng)有的大小 （即一個關(guān)鍵幀圖像的大?。?
 half2 uv = float2(i.uv.x /_HorizontalAmount, i.uv.y / _VerticalAmount); // 等價于上面3句
 
 //下面方法雖然不能和序列幀動畫一一對應(yīng)，但仍符合序列幀動畫的執(zhí)行順序
 uv.x += column / _HorizontalAmount; // 更換序列幀
 uv.y -= row / _VerticalAmount;  //等價于uv.y += 1.0 - row / _VerticalAmount; 
 
 // sample the texture
 fixed4 col = tex2D(_MainTex, uv);
 col.rgb *= _Color.rgb;   // 設(shè)置紋理顏色
 return col;
 }
 ENDCG
 }
 }
}