這篇文章將為大家詳細講解有關SQL SERVER SP的解密過程介紹，小編覺得挺實用的，因此分享給大家做個參考，希望大家閱讀完這篇文章后可以有所收獲。

成都創(chuàng)新互聯(lián)主要從事網(wǎng)站設計、成都網(wǎng)站制作、網(wǎng)頁設計、企業(yè)做網(wǎng)站、公司建網(wǎng)站等業(yè)務。立足成都服務乳山,10余年網(wǎng)站建設經(jīng)驗,價格優(yōu)惠、服務專業(yè),歡迎來電咨詢建站服務:028-86922220

在SQL SERVER里，已知微軟在加密和解密存儲過程時用的是RC4算法。下面是解密存儲過程的解題思路，讀者可以據(jù)此自己寫個解密小程序。
想解密SP，其實就是解答下列一道證明題。
已知條件：

1. 已知需要解密的存儲過程SP_A的密文為Ma。
2. 用一個已知明文的SP_B替換SP_A，這樣得到SP_B的明文和密文分別為Tb和Mb。
   求證：Ta=Ma⊕Tb⊕Mb，Ta即為需要解密的存儲過程的明文。

證明過程：

1. 用DAC登錄SQLSERVER，獲取Ma和Mb: SELECT imageval FROM sys.sysobjvalues where …
2. 由于RC4算法的加密和解密使用的是相同的秘鑰，假設秘鑰為K，那么：
   a.  Mb=Tb⊕K
   b.  根據(jù)異或運算公式，可以得到下列該存儲過程加解秘時使用的秘鑰為：
   K=K⊕0=K⊕Tb⊕Tb=(K⊕Tb)⊕Tb=(Tb⊕K)⊕Tb=Mb⊕Tb
3. 因為Ma=Ta⊕K，則再次利用異或運算公式，得到下列推導結(jié)果：
   Ta=Ta⊕0=Ta⊕(K⊕K)=(Ta⊕K)⊕K=Ma⊕K=Ma⊕Mb⊕Tb
4. 即Ta=Ma⊕Tb⊕Mb，Ta就是需要解密的存儲過程的明文。

/**Object:  StoredProcedure [dbo].[dbtwin_sp_decrypt]    Script Date: 01/01/2020 21:09:31 **/
IF  EXISTS (SELECT * FROM sys.objects WHERE object_id = OBJECT_ID(N'[dbo].[dbtwin_sp_decrypt]') AND type in (N'P', N'PC'))
DROP PROCEDURE [dbo].[dbtwin_sp_decrypt]
GO

/**Object:  StoredProcedure [dbo].[dbtwin_sp_decrypt]    Script Date: 01/01/2020 21:09:31 **/
SET ANSI_NULLS ON
GO

SET QUOTED_IDENTIFIER ON
GO

CREATE PROCEDURE [dbo].[dbtwin_sp_decrypt](@procname sysname = NULL)
AS
DECLARE @encrypted        NVARCHAR(MAX)
DECLARE @encryptedLength  INT

DECLARE @tempStr          NVARCHAR(MAX)
DECLARE @tempHead         NVARCHAR(MAX)
DECLARE @tempBody         NVARCHAR(MAX)

DECLARE @dummySp          NVARCHAR(MAX)
DECLARE @dummyEncrypted   NVARCHAR(MAX)

DECLARE @decryptedMessage NVARCHAR(MAX)
DECLARE @cnt              INT
DECLARE @decryptedChar    NCHAR(1)

SET NOCOUNT ON

SET @encrypted = (SELECT imageval FROM sys.sysobjvalues WHERE object_name(objid)=@procname)
SET @encryptedLength=DATALENGTH(@encrypted) / 2

SET @tempStr  = N'PROCEDURE ' + @procname + N' WITH ENCRYPTION AS'

BEGIN TRAN
SET @tempHead = N'ALTER ' + @tempStr
SET @tempBody = REPLICATE(N' ',(@encryptedLength - LEN(@tempHead)))
EXEC(@tempHead + @tempBody)
SET @dummyEncrypted = (SELECT imageval FROM sys.sysobjvalues WHERE object_name(objid)=@procname)
ROLLBACK TRAN

SET @dummySp =N'CREATE ' + @tempStr + @tempBody

SET @decryptedMessage =''
SET @cnt = 1

WHILE @cnt <> @encryptedLength
BEGIN
SET @decryptedChar =NCHAR(UNICODE(SUBSTRING(@encrypted,      @cnt, 1)) ^
UNICODE(SUBSTRING(@dummySp,        @cnt, 1)) ^
UNICODE(SUBSTRING(@dummyEncrypted, @cnt, 1)))
SET @decryptedChar=ISNULL(@decryptedChar,N' ')
SET @decryptedMessage = @decryptedMessage + @decryptedChar
SET @cnt = @cnt + 1
END
SELECT @decryptedMessage

GO

看完上述內(nèi)容，你們對SQL SERVER SP的解密過程大概了解了嗎？如果想了解更多相關文章內(nèi)容，歡迎關注創(chuàng)新互聯(lián)行業(yè)資訊頻道，感謝各位的閱讀！