需要安裝一個 arduino IDE 插件實現(xiàn)無需代碼直接向閃存中寫入文件。這個插件只支持?arduino IDE 1.x 版本，2.x是不能安裝的。我在本機中為了使用這個插件安裝了兩個版本的 arduino IDE。

具體安裝方式參考：3-3-2 通過Arduino IDE向閃存文件系統(tǒng)上傳文件 – 太極創(chuàng)客

#include#include#include#includeESP8266WiFiMulti wifiMulti;     // 建立ESP8266WiFiMulti對象

ESP8266WebServer esp8266_server(80);    // 建立網(wǎng)絡(luò)服務(wù)器對象，該對象用于響應(yīng)HTTP請求。監(jiān)聽端口（80）

void setup() {
  Serial.begin(9600);          // 啟動串口通訊
  Serial.println("");
  
  wifiMulti.addAP("ssid_from_AP_1", "your_password_for_AP_1"); // 將需要連接的一系列WiFi ID和密碼輸入這里
  wifiMulti.addAP("ssid_from_AP_2", "your_password_for_AP_2"); // ESP8266-NodeMCU再啟動后會掃描當(dāng)前網(wǎng)絡(luò)
  wifiMulti.addAP("ssid_from_AP_3", "your_password_for_AP_3"); // 環(huán)境查找是否有這里列出的WiFi ID。如果有
  Serial.println("Connecting ...");                            // 則嘗試使用此處存儲的密碼進行連接。
  
  int i = 0;  
  while (wifiMulti.run() != WL_CONNECTED) { // 嘗試進行wifi連接。
    delay(1000);
    Serial.print(i++); Serial.print(' ');
  }
  
  // WiFi連接成功后將通過串口監(jiān)視器輸出連接成功信息 
  Serial.println('\n');
  Serial.print("Connected to ");
  Serial.println(WiFi.SSID());              // 通過串口監(jiān)視器輸出連接的WiFi名稱
  Serial.print("IP address:\t");
  Serial.println(WiFi.localIP());           // 通過串口監(jiān)視器輸出ESP8266-NodeMCU的IP

  if(SPIFFS.begin()){                       // 啟動閃存文件系統(tǒng)
    Serial.println("SPIFFS Started.");
  } else {
    Serial.println("SPIFFS Failed to Start.");
  }
  
  esp8266_server.onNotFound(handleUserRequet);      // 告知系統(tǒng)如何處理用戶請求

  esp8266_server.begin();                           // 啟動網(wǎng)站服務(wù)
  Serial.println("HTTP server started");
}

void loop(void) {
  esp8266_server.handleClient();                    // 處理用戶請求
}

// 處理用戶瀏覽器的HTTP訪問
void handleUserRequet() {         
     
  // 獲取用戶請求網(wǎng)址信息
  String webAddress = esp8266_server.uri();
  
  // 通過handleFileRead函數(shù)處處理用戶訪問
  bool fileReadOK = handleFileRead(webAddress);

  // 如果在SPIFFS無法找到用戶訪問的資源，則回復(fù)404 (Not Found)
  if (!fileReadOK){                                                 
    esp8266_server.send(404, "text/plain", "404 Not Found"); 
  }
}

bool handleFileRead(String path) {            //處理瀏覽器HTTP訪問

  if (path.endsWith("/")) {                   // 如果訪問地址以"/"為結(jié)尾
    path = "/index.html";                     // 則將訪問地址修改為/index.html便于SPIFFS訪問
  } 
  
  String contentType = getContentType(path);  // 獲取文件類型
  
  if (SPIFFS.exists(path)) {                     // 如果訪問的文件可以在SPIFFS中找到
    File file = SPIFFS.open(path, "r");          // 則嘗試打開該文件
    esp8266_server.streamFile(file, contentType);// 并且將該文件返回給瀏覽器
    file.close();                                // 并且關(guān)閉文件
    return true;                                 // 返回true
  }
  return false;                                  // 如果文件未找到，則返回false
}

// 獲取文件類型
String getContentType(String filename){
  if(filename.endsWith(".htm")) return "text/html";
  else if(filename.endsWith(".html")) return "text/html";
  else if(filename.endsWith(".css")) return "text/css";
  else if(filename.endsWith(".js")) return "application/javascript";
  else if(filename.endsWith(".png")) return "image/png";
  else if(filename.endsWith(".gif")) return "image/gif";
  else if(filename.endsWith(".jpg")) return "image/jpeg";
  else if(filename.endsWith(".ico")) return "image/x-icon";
  else if(filename.endsWith(".xml")) return "text/xml";
  else if(filename.endsWith(".pdf")) return "application/x-pdf";
  else if(filename.endsWith(".zip")) return "application/x-zip";
  else if(filename.endsWith(".gz")) return "application/x-gzip";
  return "text/plain";
}

當(dāng)訪問 esp8266 ip的時候，即被重定向到 /index.html 打開網(wǎng)頁。?

你是否還在尋找穩(wěn)定的海外服務(wù)器提供商？創(chuàng)新互聯(lián)www.cdcxhl.cn海外機房具備T級流量清洗系統(tǒng)配攻擊溯源，準(zhǔn)確流量調(diào)度確保服務(wù)器高可用性，企業(yè)級服務(wù)器適合批量采購，新人活動首月15元起，快前往官網(wǎng)查看詳情吧