如果在windows下用nagios實(shí)現(xiàn)資源監(jiān)控，則需要用到NSClient++，這里分享一個(gè)NSClient++自定義腳本，有需要的朋友參考下。

專注于為中小企業(yè)提供網(wǎng)站設(shè)計(jì)制作、成都做網(wǎng)站服務(wù),電腦端+手機(jī)端+微信端的三站合一,更高效的管理,為中小企業(yè)鶴峰免費(fèi)做網(wǎng)站提供優(yōu)質(zhì)的服務(wù)。我們立足成都，凝聚了一批互聯(lián)網(wǎng)行業(yè)人才，有力地推動(dòng)了千余家企業(yè)的穩(wěn)健成長(zhǎng)，幫助中小企業(yè)通過網(wǎng)站建設(shè)實(shí)現(xiàn)規(guī)模擴(kuò)充和轉(zhuǎn)變。

實(shí)現(xiàn)：
windows環(huán)境下nagios監(jiān)控程序的進(jìn)程關(guān)閉后自動(dòng)啟動(dòng)。

首先，編輯NSClient配置文件NSC.ini，去掉以下幾行前面的“；”號(hào)（去掉注釋，使其生效）：
 

NRPEListener.dll
script_dir=scripts\
CheckExternalScripts.dll

在NSClient安裝目錄下的scripts文件夾下，新建一個(gè)check_run.bat批處理文件，如下：
 

代碼示例:

@echo off
tasklist |find "%1" >NUL
IF ERRORLEVEL 1 GOTO err
IF ERRORLEVEL 0 GOTO ok

:err
echo CRITICAL: Process does not exist
start "" "%2\%1"
exit /B 2

:ok
echo OK: The process of normal
exit /B 0

在NSC.ini文件中[External Scripts]下面添加如下行：
 

代碼示例:

check_run=scripts\check_run.bat   Process.exe    pro/path

重啟NSClient服務(wù)。

在nagios監(jiān)控主機(jī)中，添加如下服務(wù)信息：
 

代碼示例:

define service{
        use                   generic-service
        host_name             servername
        service_description   check_processname
        check_command         check_nrpe!check_run
        }
 

重啟nagios服務(wù)，使配置生效。

監(jiān)控windows上tcp連接數(shù)：

@echo off

netstat -an | find /C "TCP" > d:\tcpcount.txt

for /f %%i in (d:\tcpcount.txt) do (

set tcpc=%%i

)

if %tcpc% GTR 5000 ( 

echo  criting: tcp connection count %tcpc%

exit /B 2

)

if not %tcpc% GTR 5000 if  %tcpc% GTR 3000 (

echo  warning: tcp connection count %tcpc%

exit /B 1

)  

if not %tcpc% GTR 3000 ( 

echo  ok: tcp connection count %tcpc%

exit /B 0

)

監(jiān)控windows文件中關(guān)鍵詞出現(xiàn)次數(shù)：

@echo off

set FILE=D:\dcsLogs\logback\pxylist\common\common-all.log

set ERROR=OutOfMemoryError

for /f "delims=" %%a in ('type %FILE%^|find /C "%ERROR%"') do set myvar=%%a

if %myvar% NEQ 0 ( 

echo CRITICAL:error count %myvar%

exit /B 2

)

if %myvar% EQU 0 ( 

echo OK:error count %myvar%

exit /B 0

)

監(jiān)控windows文件中關(guān)鍵詞出現(xiàn)次數(shù)（增加判斷文件是否存在）：

@echo off

set FILE=D:\dcsLogs\logback\pxylist\common\common-all.log

set ERROR=OutOfMemoryError

setlocal EnableDelayedExpansion

if EXIST %FILE% (

for /f "delims=" %%a in ('type %FILE%^|find /C /I "%ERROR%"') do set myvar=%%a

if !myvar! NEQ 0 ( 

echo CRITICAL:error count !myvar!-OutOfMemory,Please restart pxylist

exit /B 2

)else ( 

echo OK:error count !myvar!

exit /B 0

)

)else (

echo CRITICAL:%FILE% is not exist

exit /B 2

)

監(jiān)控windows上多個(gè)進(jìn)程名各自是否只跑了一個(gè)進(jìn)程：

@echo off

SET PROCESS1=telegraph.exe
SET PROCESS2=WindowsApplication1.exe

for /f "delims=" %%a in ('tasklist /v /nh /fo csv /fi "IMAGENAME eq %PROCESS1%"^|find /c "%PROCESS1%"') do set myvar=%%a

if %myvar% NEQ 1 (
echo CRITICAL: %PROCESS1% running %myvar% process
exit /B 2
)

for /f "delims=" %%a in ('tasklist /v /nh /fo csv /fi "IMAGENAME eq %PROCESS2%"^|find /c "%PROCESS2%"') do set myvar=%%a

if %myvar% NEQ 1 (
echo CRITICAL: %PROCESS2% running %myvar% process
exit /B 2
)

for /f "delims=" %%a in ('tasklist /nh ^|findstr "%PROCESS1% %PROCESS2%"^|find /v /c "::"') do set myvar=%%a

if %myvar% EQU 2 (
echo OK: %PROCESS1% %PROCESS2% all running 1 process
exit /B 0
)

----------------------------------------------------------------------------------

Exit

退出當(dāng)前批處理腳本或 Cmd.exe 程序（即，命令解釋程序）并返回到曾啟動(dòng) Cmd.exe 的程序或返回到“程序管理器”。

語(yǔ)法

exit[/b] [ExitCode]

參數(shù)

• /b

• 退出當(dāng)前批處理腳本。

• ExitCode

• 指定數(shù)字編號(hào)。

• /?

• 在命令提示符顯示幫助。

注釋

• 如果在批處理腳本之外使用 /b，就會(huì)退出 Cmd.exe。

• 如果使用 /b，Cmd.exe 將 ERRORLEVEL 設(shè)置為指定的 ExitCode。如果退出 Cmd.exe，Cmd.exe 則使用指定的 ExitCode 設(shè)置進(jìn)程退出代碼。

關(guān)于 exit /b[ExitCode]的詳解：

功能：Cmd.exe 將 ERRORLEVEL 設(shè)置為指定的 ExitCode。如果退出 Cmd.exe，Cmd.exe 則使用指定的 ExitCode 設(shè)置進(jìn)程退出代碼。

示例：leo.bat。

然后，我們?cè)?CMD 命令提示符下進(jìn)行操作：

執(zhí)行：leo.bat

執(zhí)行：Echo %errorlevel%

30194447